Sub normalitemインポート()

'JAN があるシートの読み込み

    Dim ws As Worksheet
    Dim csvPath As String
    Dim txtLine As String
    Dim dataArr As Variant
    Dim rowNum As Long
    Dim colNum As Integer
    Dim fNum As Integer
    Dim cleanedValue As String
    Dim catalogIDColumn As Integer
    
    
   
    ' CSVファイルを選択
    csvPath = Application.GetOpenFilename("CSVファイル (*.csv), *.csv", , "CSVを選択してください")
    If csvPath = "False" Then Exit Sub ' キャンセルされた場合は処理終了
    

   ' "normal-item"という名前のシートに切り替える
    Sheets("normal-item").Activate
    
    
    ' シートを設定
     ' normalitemにインポート
    Set ws = ThisWorkbook.Sheets("normal-item")
    
    ' シートをクリア
    ws.Cells.Clear
    
    ' ファイルを開く
    fNum = FreeFile
    Open csvPath For Input As #fNum
    
    
    ' カタログID列のみ文字列
    ' 1行目を読み込んでカタログID列を探す
    Line Input #fNum, txtLine
    dataArr = Split(txtLine, ",") ' カンマ区切りを配列に変換
    catalogIDColumn = -1
    For colNum = LBound(dataArr) To UBound(dataArr)
        If Trim(dataArr(colNum)) = "カタログID" Then
            catalogIDColumn = colNum + 1
            Exit For
        End If
    Next colNum
    
    If catalogIDColumn = -1 Then
        MsgBox "カタログID列が見つかりませんでした。", vbExclamation
        Close #fNum
        Exit Sub
    End If
    
    ' 1行目をシートに書き込む
    For colNum = LBound(dataArr) To UBound(dataArr)
        cleanedValue = Trim(dataArr(colNum))
        If Left(cleanedValue, 1) = """" And Right(cleanedValue, 1) = """" Then
            cleanedValue = Mid(cleanedValue, 2, Len(cleanedValue) - 2)
        End If
        cleanedValue = Replace(cleanedValue, """""", """")
        ws.Cells(1, colNum + 1).Value = cleanedValue
    Next colNum
    
    ' 残りの行を読み込んで処理
    rowNum = 2
    Do Until EOF(fNum)
        Line Input #fNum, txtLine
        dataArr = Split(txtLine, ",") ' カンマ区切りを配列に変換
        
        ' 各セルにデータを挿入
        For colNum = LBound(dataArr) To UBound(dataArr)
            cleanedValue = Trim(dataArr(colNum))
            
            ' 先頭と末尾がダブルクオートなら削除（"abc" → abc）
            If Left(cleanedValue, 1) = """" And Right(cleanedValue, 1) = """" Then
                cleanedValue = Mid(cleanedValue, 2, Len(cleanedValue) - 2)
            End If
            
            ' セル内の ""（二重ダブルクオート）を " に置き換え
            cleanedValue = Replace(cleanedValue, """""", """")
            
            ' カタログID列のみテキスト形式に設定
            If colNum + 1 = catalogIDColumn Then
                ws.Cells(rowNum, colNum + 1).NumberFormat = "@"
            Else
                ' 他の列は標準の書式
                ws.Cells(rowNum, colNum + 1).NumberFormat = "General"
            End If
            
            ws.Cells(rowNum, colNum + 1).Value = cleanedValue
        Next colNum
        
        rowNum = rowNum + 1
    Loop
    
    ' ファイルを閉じる
    Close #fNum
    
    MsgBox "CSVのインポートが完了しました。", vbInformation
End Sub